LP1847800 Admin grid filter display, default fields, IDL repairs
[working/Evergreen.git] / configure.ac
1 # Copyright (C) 2008 Equinox Software, Inc.
2 # Kevin Beswick <kevinbeswick00@gmail.com>
3 # Copyright (C) 2010 Laurentian University 
4 # Dan Scott <dscott@laurentian.ca>
5 #
6 # This program is free software; you can redistribute it and/or
7 # modify it under the terms of the GNU General Public License
8 # as published by the Free Software Foundation; either version 2
9 # of the License, or (at your option) any later version.
10 #
11 # This program is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15
16
17 #---------------------------
18 # Init
19 #---------------------------
20
21 export PATH=${PATH}:/usr/sbin
22 AC_PREREQ(2.61)
23 AC_INIT(Open-ILS, trunk, open-ils-dev@list.georgialibraries.org)
24 AC_CONFIG_SRCDIR([configure.ac])
25 AC_CONFIG_MACRO_DIR([m4])
26 AM_INIT_AUTOMAKE
27 AC_REVISION($Revision: 0.1 $)
28 AC_CONFIG_SUBDIRS([Open-ILS/xul/staff_client/external/libmar])
29 AC_SUBST(prefix)
30 AC_SUBST([abs_top_builddir])
31 #-----------------------------------
32 # Checks for programs.
33 #-----------------------------------
34
35
36 AC_PROG_LIBTOOL
37 AC_PROG_CC
38 AC_PROG_INSTALL
39 AC_PROG_LN_S
40 AC_PROG_MAKE_SET
41 AC_PROG_MKDIR_P
42 AM_PROG_CC_C_O
43
44 #-----------------------------------
45 # Install options 
46 #-----------------------------------
47
48 # install openils-all?
49 #AC_ARG_ENABLE([openils-all],
50 #[  --enable-openils-all    enables the installation of the default openils system (base system,web,staffclient) ],
51 #[case "${enableval}" in
52 #    yes) openils_all=true;
53 #     openils_core=true;
54 #     openils_web=true;
55 #     openils_updates=true;
56 #     openils_reporter=true;
57 #     openils_client_xul=true;
58 #     openils_server_xul=true ;;
59 #    no)  openils_all=false ;;
60 #  *) AC_MSG_ERROR([please choose another value for --enable-openils-all (supported values are yes or no])
61 #esac],
62 #[openils_all=false])
63
64 # install evergreen-core?
65 AC_ARG_ENABLE([core],
66 [  --disable-core    disables installation of the Evergreen core components ],
67 [case "${enableval}" in
68     yes) openils_core=true ;;
69     no)  openils_core=false ;;
70   *) AC_MSG_ERROR([please choose another value for --disable-core (supported values are yes or no])
71 esac],
72 [openils_core=true])
73
74 AM_CONDITIONAL([BUILDILSCORE], [test x$openils_core = xtrue])
75
76 # install evergreen-web?
77
78 AC_ARG_ENABLE([web],
79 [  --disable-web    disables installation of the Evergreen web modules ],
80 [case "${enableval}" in
81     yes) openils_web=true ;;
82     no)  openils_web=false ;;
83   *) AC_MSG_ERROR([please choose another value for --disable-web (supported values are yes or no])
84 esac],
85 [openils_web=true])
86
87 AM_CONDITIONAL([BUILDILSWEB], [test x$openils_web = xtrue])
88
89 # install evergreen-updates?
90
91 AC_ARG_ENABLE([updates],
92 [  --disable-updates    disables installation of the Evergreen updates folder ],
93 [case "${enableval}" in
94     yes) openils_updates=true ;;
95     no)  openils_updates=false ;;
96   *) AC_MSG_ERROR([please choose another value for --disable-updates (supported values are yes or no])
97 esac],
98 [openils_updates=true])
99
100 AM_CONDITIONAL([BUILDILSUPDATES], [test x$openils_updates = xtrue])
101
102 # Default updates host?
103 AC_ARG_WITH([updateshost],
104 [  --with-updateshost=hostname    default hostname for automatic updates (default is blank)],
105 [AUTOUPDATE_HOST=${withval}],
106 [AUTOUPDATE_HOST=])
107 AC_SUBST([AUTOUPDATE_HOST])
108
109 # Default updates host?
110 AC_ARG_WITH([initialhost],
111 [  --with-initialhost=hostname    default hostname for staff client (default is blank)],
112 [INITIAL_HOST=${withval}],
113 [INITIAL_HOST=])
114 AC_SUBST([INITIAL_HOST])
115
116
117 # install Evergreen Apache modules?
118 AC_ARG_ENABLE([apache-modules],
119 [  --disable-apache-modules    disables installation of the Evergreen Apache modules ],
120 [case "${enableval}" in
121     yes) build_apachemods=true ;;
122     no)  build_apachemods=false ;;
123   *) AC_MSG_ERROR([please choose another value for --disable-apache-modules (supported values are yes or no])
124 esac],
125 [build_apachemods=true])
126
127 AM_CONDITIONAL([BUILDAPACHEMODS], [test x$build_apachemods = xtrue])
128
129 # build evergreen-reporter ?
130
131 AC_ARG_ENABLE([reporter],
132 [  --disable-reporter    disables installation of the Evergreen reporter module ],
133 [case "${enableval}" in
134     yes) openils_reporter=true ;;
135     no)  openils_reporter=false ;;
136   *) AC_MSG_ERROR([please choose another value for --disable-reporter (supported values are yes or no])
137 esac],
138 [openils_reporter=true])
139
140 AM_CONDITIONAL([BUILDILSREPORTER], [test x$openils_reporter = xtrue])
141
142 # build evergreen-client ?
143
144 AC_ARG_ENABLE([client],
145 [  --disable-client    disables installation of the Evergreen staff client ],
146 [case "${enableval}" in
147     yes) openils_client=true ;;
148     no)  openils_client=false ;;
149   *) AC_MSG_ERROR([please choose another value for --disable-client (supported values are yes or no])
150 esac],
151 [openils_client=true])
152
153 AM_CONDITIONAL([BUILDILSCLIENT], [test x$openils_client = xtrue])
154
155
156 # build evergreen java ?
157
158 AC_ARG_ENABLE([java],
159 [  --enable-java    enables installation of the Evergreen Java components ],
160 [case "${enableval}" in
161     yes) evergreen_java=true ;;
162     no)  evergreen_java=false ;;
163   *) AC_MSG_ERROR([please choose another value for --enable-java (supported values are yes or no])
164 esac],
165 [evergreen_java=false])
166
167 AM_CONDITIONAL([BUILDEGJAVA], [test x$evergreen_java = xtrue])
168
169
170 # build the evergreen python modules?
171
172 AC_ARG_ENABLE([python],
173 [  --enable-python    enables installation of the Evergreen Python modules ],
174 [case "${enableval}" in
175     yes) EG_PYTHON_INSTALL=true ;;
176     no)  EG_PYTHON_INSTALL=false ;;
177   *) AC_MSG_ERROR([please choose another value for --enable-python (supported values are yes or no)])
178 esac],
179 [EG_PYTHON_INSTALL=false])
180
181 AM_CONDITIONAL([BUILDEGPYTHON], [test x$EG_PYTHON_INSTALL = xtrue])
182
183 #-----------------------------------
184 # Check for dependencies 
185 #-----------------------------------
186 AC_ARG_WITH([tmp],
187 [  --with-tmp=path             location of the Evergreen temporary directory (default is /tmp) ],
188 [TMP=${withval}],
189 [TMP=/tmp])
190 AC_SUBST([TMP])
191
192 AC_ARG_WITH([apxs],
193 [  --with-apxs=path            location of the apxs Apache configuration tool (default is /usr/bin/apxs2)],
194 [APXS2=${withval}],
195 [APXS2=/usr/bin/apxs2])
196
197 # If the passed in value doesn't work, try some reasonable defaults
198 # Fedora puts the file in /usr/sbin/apxs, for example
199 if ! test -x "$APXS2"; then
200     for i in /usr/bin /usr/sbin /usr/local/apache/bin /usr/local/apache2/bin ; do
201         for j in apxs apxs2 ; do
202             if test -x "$i/$j"; then
203                 APXS2="$i/$j"
204                 break
205             fi
206         done
207     done
208 fi
209 AC_SUBST([APXS2])
210
211 AC_ARG_WITH([libxml2],
212 [  --with-libxml2=path         location of the libxml2 headers (default is /usr/include/libxml2)],
213 [LIBXML2_HEADERS=${withval}],
214 [LIBXML2_HEADERS=/usr/include/libxml2/])
215 AC_SUBST([LIBXML2_HEADERS])
216
217 AC_ARG_WITH([dbi],
218 [  --with-dbi=path             location of the libdbi driver libraries (default is /usr/lib/x86_64-linux-gnu/dbd/)],
219 [DBI_LIBS=${withval}],
220 [DBI_LIBS=/usr/lib/x86_64-linux-gnu/dbd/])
221
222 AC_ARG_WITH([perlbase],
223 [  --with-perlbase=path        base location to install Perl modules (default based on Config.pm)],
224 [PERL_BASE=${withval}],
225 [PERL_BASE=x])
226 AC_SUBST([PERL_BASE])
227
228 # If the passed in value doesn't work, fall back to reasonable defaults
229 # Distributions are starting to package a good version of libdbi / libdbd
230 if ! test -d "$DBI_LIBS"; then
231     for i in /usr/lib/dbd/ /usr/lib64/dbd /usr/local/lib/dbd/ ; do
232         if test -d "$i"; then
233             DBI_LIBS="$i"
234             break
235         fi
236     done
237 fi
238 AC_SUBST([DBI_LIBS])
239
240 AM_CONDITIONAL(CHECK_TESTS, test x$enable_tests = xyes)
241
242 if test "x$openils_core" = "xtrue"; then
243
244     AC_PATH_PROG([OSRF_CONFIG], [osrf_config])
245     if test "x$OSRF_CONFIG" == "x"; then
246         AC_MSG_ERROR([Could not find osrf_config.
247         Ensure OpenSRF is installed and that the PATH environment variable includes
248         the OpenSRF executables. For example: PATH=\$PATH:/openils/bin ./configure])
249     fi
250
251     AC_ARG_WITH([opensrf-headers],
252     [  --with-opensrf-headers=path location of the OpenSRF header files],
253     [OPENSRF_HEADERS=${withval}],
254     [OPENSRF_HEADERS=`$OSRF_CONFIG --includedir`])
255     AC_SUBST([OPENSRF_HEADERS])
256
257     # We need this for JavaScript
258     AC_ARG_WITH([opensrf-libs],
259     [  --with-opensrf-libs=path    location of the OpenSRF libraries],
260     [OPENSRF_LIBS=${withval}],
261     [OPENSRF_LIBS=`$OSRF_CONFIG --libdir`])
262     AC_SUBST([OPENSRF_LIBS])
263
264     AC_CHECK_PROG([MEMCACHED],memcached,yes,no)
265     if test $MEMCACHED = "no"; then
266         AC_MSG_ERROR([*** memcached not found, aborting])
267     fi
268
269     AC_CHECK_PROG([ASPELL],aspell,yes,no)
270     if test $ASPELL = "no"; then
271         AC_MSG_ERROR([*** aspell not found, aborting])
272     fi
273
274     AC_CHECK_PROG([CPAN],cpan,yes,no)
275     if test $CPAN = "no"; then
276         AC_MSG_ERROR([*** cpan not found, aborting])
277     fi
278
279     AC_CHECK_PROG([YAZ],yaz-config,yes,no)
280     if test $YAZ = "no"; then
281         AC_MSG_ERROR([*** yaz not found, aborting])
282     fi
283
284     AC_CHECK_PROG([PERL],perl,yes,no)
285     if test $PERL = "no"; then 
286         AC_MSG_ERROR([*** perl not found, aborting])
287     fi
288
289     #------------------------------------
290     # Checks for libraries. 
291     #------------------------------------
292
293     # Check for the rest of the libraries
294
295     #check for dynamic linking functions
296     AC_CHECK_LIB(dl,dlopen)
297
298     #check for the libdbi library
299     AC_CHECK_LIB(dbi,dbi_initialize)
300
301     #to check for the availability and function of a particular
302     #driver we need a runtime check (since the driver is loaded
303     #dynamically). This example checks for the mysql driver
304     AC_MSG_CHECKING([for libdbi pgsql driver (dynamic load)])
305     AC_RUN_IFELSE(
306       [AC_LANG_PROGRAM(,
307         [[dbi_initialize(0); return(dbi_conn_new("pgsql") ? 0 : 1);]])],
308       [AC_MSG_RESULT("yes")],
309       [AC_MSG_FAILURE("pgsql driver not installed?")])
310
311     AC_CHECK_LIB([expat], [main], [], AC_MSG_ERROR(*** OpenILS requires libexpat))
312     AC_CHECK_LIB([ncurses], [main], [], AC_MSG_ERROR(*** OpenILS requires libncurses))
313
314     # IF the OpenSRF libs are installed in a non-standard location, such as
315     # /openils/lib, the compilation test will fail. Support that case.
316     LDFLAGS="-L$OPENSRF_LIBS"
317
318     AC_CHECK_LIB([opensrf], [osrfMessageFree], [], AC_MSG_ERROR(*** OpenILS requires libopensrf))
319     AC_CHECK_LIB([readline], [main], [], AC_MSG_ERROR(*** OpenILS requires libreadline))
320     AC_CHECK_LIB([xml2], [main], [], AC_MSG_ERROR(*** OpenILS requires libxml2))
321     AC_CHECK_LIB([xslt], [main], [], AC_MSG_ERROR(*** OpenILS requires libxslt))
322     AC_CHECK_LIB([pq], [main], [], AC_MSG_ERROR(*** OpenILS requires libpq))
323     PKG_CHECK_MODULES(pcre, libpcre >= 3.0.0)
324
325
326     #------------------------------------
327     # Checks for header files.
328     #------------------------------------
329
330     AC_HEADER_STDC
331     AC_CHECK_HEADERS([fcntl.h langinfo.h locale.h stdlib.h string.h unistd.h])
332
333     #-------------------------------------------------------------------
334     # Checks for typedefs, structures, and compiler characteristics.
335     #-------------------------------------------------------------------
336
337     AC_C_CONST
338     AC_TYPE_SIZE_T
339     AC_STRUCT_TM
340     AC_HEADER_STDBOOL
341
342     #-------------------------------------------------------------------
343     # Checks for library functions.
344     #-------------------------------------------------------------------
345
346     AC_FUNC_STRFTIME
347     AC_FUNC_STRTOD
348     AC_CHECK_FUNCS([localtime_r memset nl_langinfo setlocale strcasecmp strchr strdup strerror strncasecmp])
349
350     #---------------------------------
351     # Check for unit test framework.
352     #---------------------------------
353     PKG_CHECK_MODULES([CHECK], [check >= 0.9.0], [enable_tests=yes],
354                       [enable_tests=no])
355     if test "x$enable_tests" = "xno"; then
356         AC_MSG_WARN(Check unit testing framework not found.)
357     fi
358
359     #----------------------------
360     # Create Makefiles/Output
361     #----------------------------
362
363     AC_CONFIG_FILES([Open-ILS/examples/Makefile
364              Open-ILS/src/c-apps/Makefile
365              Open-ILS/src/c-apps/tests/Makefile
366              Open-ILS/src/extras/Makefile
367              Open-ILS/src/java/Makefile
368              Open-ILS/src/python/Makefile])
369 fi
370
371 if test "x$build_apachemods" = "xtrue"; then
372
373     #-----------------------------------
374     # Set install path variables 
375     #-----------------------------------
376
377     #APACHE PREFORK DEV TEST
378     AC_MSG_CHECKING([APXS2])
379     if test -x "${APXS2}"; then
380     AC_MSG_RESULT([yes])
381     else
382     AC_MSG_ERROR([*** apxs not found in ${APXS2}, aborting])
383     fi  
384
385     AC_CONFIG_FILES([Open-ILS/src/apachemods/Makefile])
386 fi
387
388 AC_CONFIG_FILES([Makefile
389          Open-ILS/src/Makefile
390          Open-ILS/src/perlmods/Makefile
391          Open-ILS/web/Makefile
392          Open-ILS/updates/Makefile
393          Open-ILS/xul/staff_client/Makefile
394          Open-ILS/src/extras/eg_config
395          ],
396         [
397             if test -e "./Open-ILS/src/extras/eg_config"; then chmod 755 Open-ILS/src/extras/eg_config; fi;
398         ])
399 AC_OUTPUT
400
401 #-------------------------------------------------
402 # OUTPUT STUFF 
403 #-------------------------------------------------
404
405 AC_MSG_RESULT([])
406 AC_MSG_RESULT([--------------------- Configuration options:  -----------------------])
407
408 AC_MSG_RESULT([])
409 AC_MSG_RESULT([-------- Installation Options: --------])
410 if test "$openils_core" = "true" ; then
411     AC_MSG_RESULT([Evergreen Core:          yes])
412 else
413     AC_MSG_RESULT([Evergreen Core:          no])
414 fi
415 if test "$build_apachemods" = "true" ; then
416 AC_MSG_RESULT([Evergreen Apache module:     yes])
417     else
418 AC_MSG_RESULT([Evergreen Apache module:     no])
419     fi
420     if test "$openils_web" = "true" ; then
421 AC_MSG_RESULT([Evergreen Web:               yes])
422     else
423 AC_MSG_RESULT([Evergreen Web:               no])
424     fi
425     if test "$openils_updates" = "true" ; then
426 AC_MSG_RESULT([Evergreen Updates:           yes])
427     else
428 AC_MSG_RESULT([Evergreen Updates:           no])
429     fi
430     if test "$openils_reporter" = "true" ; then
431 AC_MSG_RESULT([Evergreen Reporter:          yes])
432     else
433 AC_MSG_RESULT([Evergreen Reporter:          no])
434     fi
435     if test "$openils_client" = "true" ; then
436 AC_MSG_RESULT([Evergreen Staff Client:      yes])
437     else
438 AC_MSG_RESULT([Evergreen Staff Client:      no])
439     fi
440     if test "$EG_PYTHON_INSTALL" = "true" ; then
441 AC_MSG_RESULT([Evergreen Python Components: yes])
442     else
443 AC_MSG_RESULT([Evergreen Python Components: no])
444     fi
445     if test "$evergreen_java" = "true" ; then
446 AC_MSG_RESULT([Evergreen Java Components:   yes])
447     else
448 AC_MSG_RESULT([Evergreen Java Components:   no])
449 fi
450 AC_MSG_RESULT([]) 
451 AC_MSG_RESULT([-------- Installation Directories --------])
452 AC_MSG_RESULT(Installation directory prefix:            ${prefix})
453 AC_MSG_RESULT(Temporary directory:                      ${TMP})
454 AC_MSG_RESULT(APXS2 location:                           ${APXS2})
455 AC_MSG_RESULT(libxml2 headers location:                 ${LIBXML2_HEADERS})
456 AC_MSG_RESULT(libdbi location:                          ${DBI_LIBS})
457 AC_MSG_RESULT(OpenSRF headers location:                 ${OPENSRF_HEADERS})
458 AC_MSG_RESULT(OpenSRF libraries location:               ${OPENSRF_LIBS})
459
460 AC_MSG_RESULT([----------------------------------------------------------------------])
461
462 # vim:et:ts=4:sw=4: