Open-ILS/xul/staff_client/windowssetup.nsi

   1 ; Script generated by the HM NIS Edit Script Wizard.
   2
   3 ; HM NIS Edit Wizard helper defines
   4 ; Old versions of makensis don't like this, moved to Makefile
   5 ;!define /file PRODUCT_VERSION "client/VERSION"
   6 !define PRODUCT_TAG "Master"
   7 !define PRODUCT_INSTALL_TAG "${PRODUCT_TAG}"
   8 !define UI_IMAGESET "beta"
   9 ;!define UI_IMAGESET "release"
  10 !define PRODUCT_NAME "Evergreen Staff Client ${PRODUCT_TAG}"
  11 !define PRODUCT_PUBLISHER "Evergreen Community"
  12 !define PRODUCT_WEB_SITE "http://evergreen-ils.org/"
  13 !define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\evergreen.exe"
  14 !define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
  15 !define PRODUCT_UNINST_ROOT_KEY "HKLM"
  16 !define PRODUCT_STARTMENU_REGVAL "NSIS:StartMenuDir"
  17 !ifndef PRODUCT_LICENSE
  18   !define PRODUCT_LICENSE
  19 !endif
  20
  21 !define MUI_HEADERIMAGE
  22 !define MUI_HEADERIMAGE_BITMAP "custom_images\${UI_IMAGESET}\header.bmp"
  23 !define MUI_WELCOMEFINISHPAGE_BITMAP "custom_images\${UI_IMAGESET}\install.bmp"
  24 !define MUI_UNWELCOMEFINISHPAGE_BITMAP "custom_images\${UI_IMAGESET}\uninstall.bmp"
  25
  26 ; This should improve compression, and solves some zlib related issues with extensions
  27 SetCompressor /SOLID lzma
  28
  29 ; MUI 1.67 compatible ------
  30 !include "MUI.nsh"
  31
  32 ; File Functions
  33 !include "FileFunc.nsh"
  34
  35 ; MUI Settings
  36 !define MUI_ABORTWARNING
  37 !define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\modern-install.ico"
  38 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall.ico"
  39
  40 ; Language Selection Dialog Settings
  41 !define MUI_LANGDLL_REGISTRY_ROOT "${PRODUCT_UNINST_ROOT_KEY}"
  42 !define MUI_LANGDLL_REGISTRY_KEY "${PRODUCT_UNINST_KEY}"
  43 !define MUI_LANGDLL_REGISTRY_VALUENAME "NSIS:Language"
  44
  45 ; Make the welcome page a tad less verbose on the name
  46 ; Note: The title bar will still be verbose (full product name + version + "Setup")
  47 !define MUI_WELCOMEPAGE_TITLE "Welcome to the Evergreen Staff Client ${PRODUCT_VERSION} Setup Wizard"
  48
  49 ; Welcome page
  50 !insertmacro MUI_PAGE_WELCOME
  51 ; License page, if we have one
  52 !if "${PRODUCT_LICENSE}" != ""
  53   !insertmacro MUI_PAGE_LICENSE "${PRODUCT_LICENSE}"
  54 !endif
  55 ; Components page
  56 !ifdef AUTOUPDATE | DEVELOPER | PERMACHINE
  57 !insertmacro MUI_PAGE_COMPONENTS
  58 !endif
  59 ; Directory page
  60 !insertmacro MUI_PAGE_DIRECTORY
  61 ; Start menu page
  62 var ICONS_GROUP
  63 !define MUI_STARTMENUPAGE_NODISABLE
  64 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "Evergreen Staff Client ${PRODUCT_TAG}"
  65 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "${PRODUCT_UNINST_ROOT_KEY}"
  66 !define MUI_STARTMENUPAGE_REGISTRY_KEY "${PRODUCT_UNINST_KEY}"
  67 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "${PRODUCT_STARTMENU_REGVAL}"
  68 !insertmacro MUI_PAGE_STARTMENU Application $ICONS_GROUP
  69 ; Instfiles page
  70 !insertmacro MUI_PAGE_INSTFILES
  71 ; Finish page
  72 !define MUI_FINISHPAGE_RUN "$INSTDIR\evergreen.exe"
  73 !insertmacro MUI_PAGE_FINISH
  74
  75 ; Uninstaller pages
  76 !insertmacro MUI_UNPAGE_INSTFILES
  77
  78 ; Language files
  79 !insertmacro MUI_LANGUAGE "English"
  80
  81 ; MUI end ------
  82
  83 Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
  84 OutFile "evergreen_staff_client_setup.exe"
  85 InstallDir "$PROGRAMFILES\Evergreen Staff Client ${PRODUCT_INSTALL_TAG}"
  86 InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" "${PRODUCT_INSTALL_TAG}"
  87 ShowInstDetails show
  88 ShowUnInstDetails show
  89 RequestExecutionLevel admin
  90
  91 Section "Staff Client" SECMAIN
  92   SetShellVarContext All ; All Users (for shortcuts)
  93   ; Uninstall old (inno) variant?
  94   IfFileExists "$INSTDIR/unin000.exe" 0 +3
  95     ExecWait '"$INSTDIR/unins000.exe" /VERYSILENT'
  96     Sleep 5000 ; Wait five seconds in case the uninstaller returned before it was done
  97   ; Uninstall old (nsis) version?
  98   IfFileExists "$INSTDIR/uninst.exe" 0 +4
  99     ExecWait '"$INSTDIR/uninst.exe" /S _?="$INSTDIR"'
 100     Sleep 5000 ; Wait five seconds in case the uninstaller returned before it was done
 101     Delete "$INSTDIR/uninst.exe"
 102   SetOutPath "$INSTDIR"
 103   File /r /x "autoupdate.js" /x "autochannel.js" /x "developers.js" /x "aa_per_machine.js" "client\*"
 104
 105   ; Shortcuts
 106   !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 107   CreateDirectory "$SMPROGRAMS\$ICONS_GROUP"
 108   !ifdef WICON
 109   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\Evergreen Staff Client.lnk" "$INSTDIR\evergreen.exe" "" "$INSTDIR\evergreen.ico"
 110   !ifdef PROFILES
 111   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\Evergreen Staff Client Profile Manager.lnk" "$INSTDIR\evergreen.exe" "-profilemanager" "$INSTDIR\evergreen.ico"
 112   !endif
 113   !else
 114   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\Evergreen Staff Client.lnk" "$INSTDIR\evergreen.exe"
 115   !ifdef PROFILES
 116   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\Evergreen Staff Client Profile Manager.lnk" "$INSTDIR\evergreen.exe" "-profilemanager"
 117   !endif
 118   !endif
 119   CreateShortCut "$DESKTOP\Evergreen Staff Client ${PRODUCT_TAG}.lnk" "$INSTDIR\evergreen.exe"
 120
 121   ; External script for extra things.
 122   !ifdef EXTRAS
 123   !define EXTERNAL_EXTRAS_SECMAIN
 124   !include /NONFATAL "extras.nsi"
 125   !undef EXTERNAL_EXTRAS_SECMAIN
 126   !endif
 127
 128   !insertmacro MUI_STARTMENU_WRITE_END
 129
 130   !ifdef AUTOUPDATE | PERMACHINE
 131   ; For autoupdate and/or registering per machine, make sure we can write to the install directory.
 132   !addplugindir AccessControl/Plugins
 133   AccessControl::GrantOnFile "$INSTDIR" "Everyone" "FullAccess"
 134   !endif
 135 SectionEnd
 136
 137 !ifdef AUTOUPDATE
 138 Section /o "Automatic Update" SECAUTO
 139   SetOutPath "$INSTDIR\defaults\preferences"
 140   File "client\defaults\preferences\autoupdate.js"
 141   File "client\defaults\preferences\autochannel.js"
 142   SetOutPath "$INSTDIR"
 143 SectionEnd
 144 !endif
 145
 146 !ifdef DEVELOPER
 147 Section /o "Developer Options" SECDEV
 148   SetOutPath "$INSTDIR\defaults\preferences"
 149   File "client\defaults\preferences\developers.js"
 150   SetOutPath "$INSTDIR"
 151 SectionEnd
 152 !endif
 153
 154 !ifdef PERMACHINE
 155 Section /o "Registration Per Machine" SECPERMAC
 156   SetOutPath "$INSTDIR\defaults\preferences"
 157   File "client\defaults\preferences\aa_per_machine.js"
 158   SetOutPath "$INSTDIR"
 159 SectionEnd
 160 !endif
 161
 162 Function .onInit
 163   !insertmacro MUI_LANGDLL_DISPLAY
 164   SectionSetFlags ${SECMAIN} 17
 165   ; This is mainly for silent installs
 166   !ifdef AUTOUPDATE | DEVELOPER | PERMACHINE
 167     Var /GLOBAL CMD_ARGS
 168     StrCpy $CMD_ARGS ""
 169     ${GetParameters} $CMD_ARGS
 170     !ifdef AUTOUPDATE
 171       !ifdef AUTOUPDATE_NODEFAULT
 172         ${GetOptions} $CMD_ARGS "/autoupdate" $0
 173         IfErrors +2 0
 174       !else
 175         ${GetOptions} $CMD_ARGS "/noautoupdate" $0
 176         IfErrors 0 +2
 177       !endif
 178       SectionSetFlags ${SECAUTO} 1
 179     !endif
 180     !ifdef PERMACHINE
 181       !ifdef PERMACHINE_NODEFAULT
 182         ${GetOptions} $CMD_ARGS "/permachine" $0
 183         IfErrors +2 0
 184       !else
 185         ${GetOptions} $CMD_ARGS "/nopermachine" $0
 186         IfErrors 0 +2
 187       !endif
 188       SectionSetFlags ${SECPERMAC} 1
 189     !endif
 190     !ifdef DEVELOPER
 191       ${GetOptions} $CMD_ARGS "/developer" $0
 192       IfErrors +2 0
 193       SectionSetFlags ${SECDEV} 1
 194     !endif
 195   !endif
 196 FunctionEnd
 197
 198 Section -AdditionalIcons
 199   !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 200   WriteIniStr "$INSTDIR\${PRODUCT_NAME}.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
 201   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\Website.lnk" "$INSTDIR\${PRODUCT_NAME}.url"
 202   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\Uninstall.lnk" "$INSTDIR\uninst.exe"
 203   !insertmacro MUI_STARTMENU_WRITE_END
 204 SectionEnd
 205
 206 Section -Post
 207   WriteUninstaller "$INSTDIR\uninst.exe"
 208   WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\evergreen.exe"
 209   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
 210   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
 211   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\evergreen.exe"
 212   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
 213   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
 214   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
 215 SectionEnd
 216
 217 ; Section descriptions
 218 !ifdef AUTOUPDATE | DEVELOPER | PERMACHINE
 219 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 220   !insertmacro MUI_DESCRIPTION_TEXT ${SECMAIN} "The Evergreen Staff Client with XULRunner, Required"
 221   !ifdef AUTOUPDATE
 222   !insertmacro MUI_DESCRIPTION_TEXT ${SECAUTO} "Automatic Update Functionality"
 223   !endif
 224   !ifdef DEVELOPER
 225   !insertmacro MUI_DESCRIPTION_TEXT ${SECDEV}  "Developer Options"
 226   !endif
 227   !ifdef PERMACHINE
 228   !insertmacro MUI_DESCRIPTION_TEXT ${SECPERMAC}  "Default registration and offline storage to per machine instead of per user"
 229   !endif
 230 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 231 !endif
 232
 233 Function un.onUninstSuccess
 234   HideWindow
 235   MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) was successfully removed from your computer." /SD IDOK
 236 FunctionEnd
 237
 238 Function un.onInit
 239 !insertmacro MUI_UNGETLANGUAGE
 240   MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Are you sure you want to completely remove $(^Name) and all of its components?" /SD IDYES IDYES +2
 241   Abort
 242 FunctionEnd
 243
 244 Function "un.RemoveFileCheck"
 245   StrCmp $R7 "open_ils_staff_client" +5
 246   StrCmp $R6 "" +3
 247   Delete "$R9"
 248   Goto +2
 249   RmDir /r "$R9"
 250   Push $0
 251 FunctionEnd
 252
 253 Section Uninstall
 254   SetShellVarContext All ; All Users (for shortcuts)
 255   !insertmacro MUI_STARTMENU_GETFOLDER "Application" $ICONS_GROUP
 256   Delete "$INSTDIR\${PRODUCT_NAME}.url"
 257   Delete "$INSTDIR\uninst.exe"
 258   Delete "$INSTDIR\evergreen.exe"
 259   Delete "$INSTDIR\application.ini"
 260   Delete "$INSTDIR\BUILD_ID"
 261   Delete "$INSTDIR\STAMP_ID"
 262   Delete "$INSTDIR\VERSION"
 263   Delete "$INSTDIR\install.rdf"
 264   Delete "$INSTDIR\active-update.xml"
 265   Delete "$INSTDIR\chrome.manifest"
 266   Delete "$INSTDIR\updates.xml"
 267   Delete "$INSTDIR\log.txt"
 268   Delete "$INSTDIR\evergreen.ico"
 269
 270   Delete "$SMPROGRAMS\$ICONS_GROUP\Uninstall.lnk"
 271   Delete "$SMPROGRAMS\$ICONS_GROUP\Website.lnk"
 272   Delete "$DESKTOP\Evergreen Staff Client ${PRODUCT_TAG}.lnk"
 273   Delete "$SMPROGRAMS\$ICONS_GROUP\Evergreen Staff Client.lnk"
 274
 275   ; External script for removing extra files before we wipe out the install directory
 276   !ifdef EXTRAS
 277   !define EXTERNAL_EXTRAS_UNINSTALL
 278   !include /NONFATAL "extras.nsi"
 279   !undef EXTERNAL_EXTRAS_UNINSTALL
 280   !endif
 281
 282   RMDir "$SMPROGRAMS\$ICONS_GROUP"
 283   RMDir /r "$INSTDIR\updates"
 284   RMDir /r "$INSTDIR\xulrunner"
 285   RMDir /r "$INSTDIR\extensions"
 286 ;  RMDir /r "$INSTDIR\chrome" ; We can't wipe out the chrome directory normally. Per-machine info would be lost on upgrade.
 287   RMDir /r "$INSTDIR\components"
 288   RMDir /r "$INSTDIR\defaults"
 289
 290   ; Basically, we want to remove everything but "open_ils_staff_client" from the chrome dir
 291   ; So we pass over every file and folder in it. If it matches, we leave it alone.
 292   ${Locate} "$INSTDIR\chrome" "/G=0" "un.RemoveFileCheck"
 293   ; Then, we remove the folder non-recursively, which won't wipe out the folder if it is still there.
 294   RMDir "$INSTDIR\chrome"
 295
 296   RMDir "$INSTDIR"
 297
 298   DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
 299   DeleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"
 300   SetAutoClose true
 301 SectionEnd