configure.ac

   1 # Copyright (C) 2008 Equinox Software, Inc.
   2 # Kevin Beswick <kevinbeswick00@gmail.com>
   3 # Copyright (C) 2009-2010 Dan Scott <dscott@laurentian.ca>
   4 #
   5 # This program is free software; you can redistribute it and/or
   6 # modify it under the terms of the GNU General Public License
   7 # as published by the Free Software Foundation; either version 2
   8 # of the License, or (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # Process this file with autoconf to produce a configure script.
  16
  17
  18 #-------------------------------
  19 # Initialization
  20 #-------------------------------
  21
  22 export PATH=${PATH}:/usr/sbin
  23 AC_PREREQ(2.59)
  24
  25 # Get our version number from one file
  26 m4_include([version.m4])
  27
  28 # Version number gets turned into @PACKAGE_VERSION@
  29 AC_INIT([OpenSRF],m4_defn([VERSION_NUMBER]),[open-ils-dev@list.georgialibraries.org])
  30 AM_INIT_AUTOMAKE([OpenSRF], m4_defn([VERSION_NUMBER]))
  31
  32 AC_REVISION($Revision: 0.1 $)
  33 AC_CONFIG_SRCDIR([configure.ac])
  34 AC_PREFIX_DEFAULT([/opensrf])
  35
  36 # Enable $prefix to resolve to a reasonable value in substitutions in
  37 # scripts if no explict value was passed in to configure
  38 if test "$prefix" == "NONE"; then
  39    prefix=$ac_default_prefix
  40 fi
  41
  42 # Perl and Python scripts don't want ${prefix} if no value was specified
  43 eval "eval CONF_DIR=$sysconfdir"
  44 eval "eval PID_DIR=$localstatedir"
  45 AC_SUBST([CONF_DIR])
  46 AC_SUBST([PID_DIR])
  47
  48 AC_SUBST(prefix)
  49 AC_SUBST(bindir)
  50
  51
  52 AC_DEFUN([AC_PYTHON_MOD],[
  53     if test -z $PYTHON;
  54     then
  55         PYTHON="python"
  56     fi
  57     AC_MSG_CHECKING($PYTHON_NAME module: $1)
  58         $PYTHON -c "import $1" 2>/dev/null
  59         if test $? -eq 0;
  60         then
  61                 AC_MSG_RESULT(yes)
  62                 eval AS_TR_CPP(HAVE_PYMOD_$1)=yes
  63         else
  64                 AC_MSG_ERROR(failed to find required module $1)
  65                 exit 1
  66         fi
  67 ])
  68
  69 #-------------------------------
  70 # Installation options
  71 #-------------------------------
  72
  73 # build and install the java libs?
  74 AC_ARG_ENABLE([java],
  75 [  --enable-java    enable building and installing the java libraries],
  76 [case "${enableval}" in
  77     yes) OSRF_INSTALL_JAVA=true ;;
  78     no) OSRF_INSTALL_JAVA=false ;;
  79   *) AC_MSG_ERROR([please choose another value for --enable-java (supported values are yes or no)]) ;;
  80 esac],
  81 [OSRF_INSTALL_JAVA=false])
  82
  83 AM_CONDITIONAL([BUILDJAVA], [test x$OSRF_INSTALL_JAVA = xtrue])
  84 AC_SUBST([OSRF_INSTALL_JAVA])
  85
  86 # install the javascript files?
  87 AC_ARG_ENABLE([javascript],
  88 [  --disable-javascript    disable installing JavaScript libraries],
  89 [case "${enableval}" in
  90     yes) OSRF_INSTALL_JAVASCRIPT=true ;;
  91     no) OSRF_INSTALL_JAVASCRIPT=false ;;
  92   *) AC_MSG_ERROR([please choose another value for --disable-javascript (supported values are yes or no)]) ;;
  93 esac],
  94 [OSRF_INSTALL_JAVASCRIPT=true])
  95
  96 AM_CONDITIONAL([INSTALLJAVASCRIPT], [test x$OSRF_INSTALL_JAVASCRIPT = xtrue])
  97 AC_SUBST([OSRF_INSTALL_JAVASCRIPT])
  98
  99 # install the OpenSRF core files?
 100 AC_ARG_ENABLE([core],
 101 [  --disable-core    disable installing core files],
 102 [case "${enableval}" in
 103     yes) OSRF_INSTALL_CORE=true ;;
 104     no) OSRF_INSTALL_CORE=false ;;
 105   *) AC_MSG_ERROR([please choose another value for --disable-core (supported values are yes or no)]) ;;
 106 esac],
 107 [OSRF_INSTALL_CORE=true])
 108
 109 AM_CONDITIONAL([BUILDCORE], [test x$OSRF_INSTALL_CORE = xtrue])
 110 AC_SUBST([OSRF_INSTALL_CORE])
 111
 112
 113 # build and install the python modules
 114 AC_ARG_ENABLE([python],
 115 [  --enable-python  enable building and installing python modules],
 116 [case "${enableval}" in
 117   yes) OSRF_INSTALL_PYTHON=true ;;
 118   no) OSRF_INSTALL_PYTHON=false ;;
 119   *) AC_MSG_ERROR([please choose another value for --enable-python (supported values are yes or no)]) ;;
 120 esac],
 121 [OSRF_INSTALL_PYTHON=false])
 122
 123 AM_CONDITIONAL([BUILDPYTHON], [test x$OSRF_INSTALL_PYTHON = xtrue])
 124 AC_SUBST([OSRF_INSTALL_PYTHON])
 125
 126 # enable chopchop, the basic XMPP server
 127
 128 AC_ARG_ENABLE([chopchop],
 129 [  --enable-chopchop    build and install chopchop, a basic XMPP server],
 130 [case "${enableval}" in
 131     yes) OSRF_INSTALL_CHOPCHOP=true ;;
 132     no) OSRF_INSTALL_CHOPCHOP=false ;;
 133   *) AC_MSG_ERROR([please choose another value for --enable-chopchop (supported values are yes or no)]) ;;
 134 esac],
 135 [OSRF_INSTALL_CHOPCHOP=false])
 136
 137 AM_CONDITIONAL([BUILDCHOPCHOP], [test x$OSRF_INSTALL_CHOPCHOP = xtrue])
 138 AC_SUBST([OSRF_INSTALL_CHOPCHOP])
 139
 140 # enable debug?
 141
 142 AC_ARG_ENABLE(debug,
 143 [  --enable-debug    Turn on debugging],
 144 [case "${enableval}" in
 145   yes) debug=true ;;
 146   no)  debug=false ;;
 147   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 148 esac],[debug=false])
 149 AM_CONDITIONAL(DEBUG, test x$debug = xtrue)
 150
 151 # path to the directory containing the java dependency jar files (included if java installs)
 152 if test $OSRF_INSTALL_JAVA; then
 153         AC_SUBST([OSRF_JAVA_DEPSDIR], [/opt/java])
 154     AC_CONFIG_FILES([src/java/Makefile])
 155 fi
 156
 157 #--------------------------------
 158 # Checks for programs.
 159 #--------------------------------
 160
 161 AC_PROG_LIBTOOL
 162 AC_PROG_AWK
 163 AC_PROG_CC
 164 AC_PROG_INSTALL
 165 AC_PROG_MAKE_SET
 166
 167 #------------------------------
 168 # Set install path variables
 169 #------------------------------
 170 AC_ARG_WITH([tmp],
 171 [  --with-tmp=path                  location for the temporary directory for OpenSRF (default is /tmp)],
 172 [TMP=${withval}],
 173 [TMP=/tmp])
 174 AC_SUBST([TMP])
 175
 176 AC_ARG_WITH([apxs],
 177 [  --with-apxs=path                 location of the apxs (Apache extension) tool (default is /usr/bin/apxs2)],
 178 [APXS2=${withval}],
 179 [APXS2=/usr/bin/apxs2])
 180 if ! test -x "$APXS2"; then
 181         for i in /usr/bin /usr/sbin /usr/local/apache/bin /usr/local/apache2/bin ; do
 182                 for j in apxs apxs2 ; do
 183                         if test -x "$i/$j"; then
 184                                 APXS2="$i/$j"
 185                                 break
 186                         fi
 187                 done
 188         done
 189 fi
 190 AC_SUBST([APXS2])
 191
 192 AC_ARG_WITH([apache],
 193 [  --with-apache=path               location of the Apache headers (default is /usr/include/apache2)],
 194 [APACHE2_HEADERS=${withval}],
 195 [APACHE2_HEADERS=/usr/include/apache2])
 196 if ! test -d "$APACHE2_HEADERS"; then
 197         for i in /usr/include/httpd ; do
 198                 if test -d "$i"; then
 199                         APACHE2_HEADERS="$i"
 200                         break
 201                 fi
 202         done
 203 fi
 204 AC_SUBST([APACHE2_HEADERS])
 205
 206 AC_ARG_WITH([apr],
 207 [  --with-apr=path                  location of the Apache Portable Runtime headers (default is /usr/include/apr-1.0/)],
 208 [APR_HEADERS=${withval}],
 209 [APR_HEADERS=/usr/include/apr-1.0])
 210 if ! test -d "$APR_HEADERS"; then
 211         for i in /usr/include/apr-1 ; do
 212                 if test -d "$i"; then
 213                         APR_HEADERS="$i"
 214                         break
 215                 fi
 216         done
 217 fi
 218 AC_SUBST([APR_HEADERS])
 219
 220 AC_ARG_WITH([libxml],
 221 [  --with-libxml=path               location of the libxml2 headers (default is /usr/include/libxml2/))],
 222 [LIBXML2_HEADERS=${withval}],
 223 [LIBXML2_HEADERS=/usr/include/libxml2/])
 224 AC_SUBST([LIBXML2_HEADERS])
 225
 226 AC_ARG_WITH([includes],
 227 [  --with-includes=DIRECTORIES      a colon-separated list of directories that will be added to the list the compiler searches for header files (Example: --with-includes=/path/headers:/anotherpath/moreheaders)],
 228 [EXTRA_USER_INCLUDES=${withval}])
 229
 230 AC_ARG_WITH([libraries],
 231 [  --with-libraries=DIRECTORIES     a colon-separated list of directories to search for libraries (Example: --with-libraries=/lib:/usr/lib)],
 232 [EXTRA_USER_LIBRARIES=${withval}])
 233
 234 # Change these lists to proper compiler/linker options
 235
 236 IFSBAK=${IFS}
 237 IFS="${IFS}:"
 238
 239 for dir in $EXTRA_USER_INCLUDES; do
 240         if test -d "$dir"; then
 241           INCLUDES="$INCLUDES -I$dir"
 242         else
 243           AC_MSG_WARN([*** Include directory $dir does not exist.])
 244         fi
 245 done
 246 AC_SUBST(INCLUDES)
 247
 248 for dir in $EXTRA_USER_LIBRARIES; do
 249         if test -d "$dir"; then
 250           LIBDIRS="$LIBDIRS -L$dir"
 251         else
 252           AC_MSG_WARN([*** Library directory $dir does not exist.])
 253         fi
 254 done
 255 AC_SUBST(LIBDIRS)
 256
 257 IFS=${IFSBAK}
 258
 259 AC_CONFIG_FILES([Makefile
 260         src/Makefile])
 261
 262 #PYTHON TESTS
 263 if test x$OSRF_INSTALL_PYTHON = xtrue; then
 264     AC_CHECK_PROG([HAVE_PYTHON],python,yes,no)
 265     if test $HAVE_PYTHON = "no"; then
 266         AC_MSG_ERROR([*** python not found, aborting])
 267     fi
 268     AC_PYTHON_MOD([setuptools])
 269     AC_CONFIG_FILES([
 270         examples/math_client.py
 271         examples/simple_text.py
 272         src/python/Makefile
 273     ])
 274 fi
 275 # Check Unit test framework
 276 PKG_CHECK_MODULES([CHECK], [check >= 0.9.0], [enable_tests=yes],
 277                   [enable_tests=no])
 278 AM_CONDITIONAL(CHECK_TESTS, test x$enable_tests = xyes)
 279
 280 if test "x$enable_tests" = "xno"; then
 281   AC_MSG_WARN(Check unit testing framweork not found.)
 282 fi
 283
 284 if test "x$OSRF_INSTALL_CORE" = "xtrue"; then
 285         #--------------------------------
 286         # Check for dependencies.
 287         #--------------------------------
 288
 289         #APACHE PREFORK DEV TEST
 290         AC_MSG_CHECKING([APXS])
 291         if test -f "${APXS2}"; then
 292         AC_MSG_RESULT([yes])
 293         else
 294         AC_MSG_ERROR([*** apxs not found, aborting])
 295         fi
 296
 297         #-----------------------------
 298         # Checks for libraries.
 299         #-----------------------------
 300
 301         AC_SEARCH_LIBS([dlerror], [dl], [],AC_MSG_ERROR([***OpenSRF requires a library (typically libdl) that provides dlerror()]))
 302         AC_CHECK_LIB([ncurses], [initscr], [], AC_MSG_ERROR(***OpenSRF requires ncurses development headers))
 303         AC_CHECK_LIB([readline], [readline], [], AC_MSG_ERROR(***OpenSRF requires readline development headers))
 304         AC_CHECK_LIB([xml2], [xmlAddID], [], AC_MSG_ERROR(***OpenSRF requires xml2 development headers))
 305         # Check for libmemcached and set flags accordingly
 306         PKG_CHECK_MODULES(memcached, libmemcached >= 0.8.0)
 307         AC_SUBST(memcached_CFLAGS)
 308         AC_SUBST(memcached_LIBS)
 309
 310         #-----------------------------
 311         # Checks for header files.
 312         #-----------------------------
 313
 314         AC_HEADER_STDC
 315         AC_HEADER_SYS_WAIT
 316         AC_CHECK_HEADERS([arpa/inet.h fcntl.h limits.h malloc.h netdb.h netinet/in.h stdlib.h string.h strings.h sys/socket.h sys/time.h sys/timeb.h syslog.h unistd.h])
 317
 318         #------------------------------------------------------------------
 319         # Checks for typedefs, structures, and compiler characteristics.
 320         #------------------------------------------------------------------
 321
 322         AC_C_CONST
 323         AC_C_INLINE
 324         AC_TYPE_PID_T
 325         AC_TYPE_SIZE_T
 326         AC_HEADER_TIME
 327         AC_STRUCT_TM
 328     AM_PROG_CC_C_O
 329
 330         #----------------------------------
 331         # Checks for library functions.
 332         #----------------------------------
 333
 334         AC_FUNC_FORK
 335         AC_FUNC_MALLOC
 336         AC_FUNC_SELECT_ARGTYPES
 337         AC_TYPE_SIGNAL
 338         AC_FUNC_STRFTIME
 339         AC_FUNC_STRTOD
 340         AC_FUNC_VPRINTF
 341         AC_CHECK_FUNCS([bzero dup2 gethostbyname gethostname gettimeofday malloc_stats memset select socket strcasecmp strchr strdup strerror strncasecmp strndup strrchr strtol])
 342
 343         #------------------------------------
 344         # Configuration and output
 345         #------------------------------------
 346
 347         AC_CONFIG_FILES([doc/dokuwiki-doc-stubber.pl
 348                          examples/math_xul_client/Makefile
 349                          examples/math_bench.pl
 350                          examples/multisession-test.pl
 351                          src/c-apps/Makefile
 352                          src/gateway/Makefile
 353                          src/jserver/Makefile
 354                          src/libopensrf/Makefile
 355                          src/perl/Makefile
 356                          src/ports/strn_compat/Makefile
 357                          src/python/opensrf.py
 358                          src/router/Makefile
 359                          src/srfsh/Makefile
 360              tests/Makefile
 361                          bin/opensrf-perl.pl
 362                          bin/osrf_config
 363                          bin/osrf_ctl.sh])
 364 fi
 365
 366 AC_OUTPUT
 367
 368 AC_MSG_RESULT([])
 369 AC_MSG_RESULT([--------------------- Configuration options:  -----------------------])
 370
 371 if test "$OSRF_INSTALL_JAVA" = "true" ; then
 372         AC_MSG_RESULT([OSRF install Java support?       yes])
 373         AC_MSG_RESULT([Java support files               $OSRF_JAVA_DEPSDIR])
 374 else
 375         AC_MSG_RESULT([OSRF install Java support?       no])
 376 fi
 377
 378 if test "$OSRF_INSTALL_PYTHON" = "true" ; then
 379         AC_MSG_RESULT([OSRF install Python support?     yes])
 380 else
 381         AC_MSG_RESULT([OSRF install Python support?     no])
 382 fi
 383
 384 if test "$OSRF_INSTALL_CHOPCHOP" = "true" ; then
 385         AC_MSG_RESULT([OSRF install chopchop?           yes])
 386 else
 387         AC_MSG_RESULT([OSRF install chopchop?           no])
 388 fi
 389
 390         AC_MSG_RESULT(Installation directory prefix:   ${prefix})
 391         AC_MSG_RESULT(Temporary directory:             ${TMP})
 392         AC_MSG_RESULT(APXS2 location:                  ${APXS2})
 393         AC_MSG_RESULT(Apache headers location:         ${APACHE2_HEADERS})
 394         AC_MSG_RESULT(APR headers location:            ${APR_HEADERS})
 395         AC_MSG_RESULT(libxml2 headers location:        ${LIBXML2_HEADERS})
 396
 397 AC_MSG_RESULT([----------------------------------------------------------------------])